; Mistral FX24 modem driver (V42bis)                        Version 1.00 28-Oct-1992
;
; Written by Joe Willis ----ARCADE USER joew-----
;
; Although modem is FAX capable this driver does not support FAX directly
; This is a modified version of the hayes drivers supplied with arcterm 7
;
; Anyone know how to add FAX support?

modem_initialise ()
  {
  integer oldtx=port_txspeed(),oldrx=port_rxspeed()

  port_rxclear()
  port_txspeed(19200)
  port_rxspeed(19200)
              
  type "AT"+cr
  pause(20)
  type "AT&C1&D2&K1&U3S11=100S9=6S10=50S7=55S6=10S45=10"+cr
  pause(30)
  port_rxclear()

  type "ATQ0V1\V1E0X4&C1S0=0&R0N1F0L2M1W0&E5&S1%C1"+cr
  if (waitfor("OK",150))
    {
    port_txspeed(oldtx)
    port_rxspeed(oldrx)
    return(0)
    }

  port_txspeed(oldtx)
  port_rxspeed(oldrx)
  return(1)
  }

modem_shutdown ()
  {
  return(1)
  }

modem_connect ()
  {
  integer sv=0

  if (port_txspeed()==75)
    {
    port_txspeed(1200)
    sv=8
    }

  port_dtr(1)
  port_rts(1)
  type "ATD"+cr

  return(_processmessage(""))
  }

modem_disconnect ()
  {
  type cr 
  pause(10)
  port_rts(0)
  port_dtr(0)
  pause(50)
  port_dtr(1)
  port_rts(1)
  pause(10)
  type cr
  }

modem_dial (string number[40],integer how)
  {
  string dialtype[1]
  integer sv=0

  port_dtr(1)
  port_rts(1)
  port_rxclear()

  if (how==0)
    {
    dialtype="P"
    }
  else
    {
    dialtype="T"
    }

  if (port_txspeed()==75)
    {
    port_txspeed(1200)
    sv=8
    }

  port_rxclear()
  type "ATD"+dialtype+number+cr

  return(_processmessage(""))
  }

modem_answer ()
  {
  string response[50]

  type "ATS0=1"+cr

  repeat
    {
    response=$modeminput(50,modem_replywait)
    }
  until(strcmp($left(response,7),"CONNECT")==0)

  return(_processmessage(response))
  }

modem_errorcontrol (string option[10])
  {
  set(linklevel,none)

  if (comparei(option,"off"))
    {
    type("AT&E0"+cr)
    }

  if (comparei($left(option,3),"mnp"))
    {
    integer level=val($mid(option,4,1))
 
    if (level>=5)
      {
      type("AT&E5"+cr)
      }
    else
      {
      type("AT&E5"+cr)
      }
    }

  if (comparei(option,"vasscom"))
    {
    type("AT&E0"+cr)
    set(linklevel,vasscom)
    }

  waitfor("OK"+$chr(13)+$chr(10),100)
  pause(50)
  }

modem_standard (string option[10])
  {
  integer number=val(option)

  if (comparei(option,"v21") || number==300)
    {
    type "ATN0F1"+cr
    waitfor("OK"+$chr(13)+$chr(10),100)
    prints newline+"v21 Driver Loaded"+newline
    return
    }
  if (comparei(option,"v22") || number==1200)
    {
    type "ATN0F4"+cr
    waitfor("OK"+$chr(13)+$chr(10),100)
    prints newline+"v22 Driver Loaded"+newline
    return
    }
  if (comparei(option,"v22bis") || number==2400)
    {
    type "ATN0F5"+cr
    waitfor("OK"+$chr(13)+$chr(10),100)
    prints newline+"v22bis Driver Loaded"+newline
    return
    }
  if (comparei(option,"hst") || comparei(option,"fastest") || number=19200)
    {
    type "ATN1F0"+cr
    waitfor("OK"+$chr(13)+$chr(10),100)
    prints newline+"v42bis MNP5 Driver Loaded"+newline
    return
    }
  prints "Modem standard "+option+" is not supported."+newline
  }

_processmessage (string already[50])
  {
  string retcode[50]

  if (len(already)==0)
    {
    ; Wait for message
    retcode=$modeminput(50,modem_replywait)
    if (len(retcode)==0)
      {
      retcode=$modeminput(50,modem_replywait)
      }
    }
  else
    {
    retcode=already
    }

  ; Check for NO DIAL TONE/BLACKLISTED/BUSY
  switch(retcode)
    {
    case$("BUSY")
      {
      return(2)
      }
    case$("NO DIAL TONE")
      {
      return(3)
      }
    case$("BLACKLISTED")
      {
      return(4)
      }
    }

  if (compare($left(retcode,7),"CONNECT"))
    {
    prints retcode+newline
    return(0)
    }

  modem_disconnect()
  return(1)
  }
